;:sys36864
	;.opt oo
	*= 51200
loadvec	=$330
loadold	=$f4a5
strout	=$ab1e
axout	=$bdcd
love	=$93
status	=$90
ga	=$ba
missing	=$f710
fnlen	=$b7
mem	=$ae
adr	=$c3
talk	=$ed09
second	=$edc7
sa	=$b9
iecin	=$ee13
return	=$aad7
message	=$f5d2
search	=$f5af
openfile	=$f3d5
stopkey	=$ffe1
setst	=$fe1c
fileclose	=$f633
ende	=$f5a9
nofound	=$f704
untalk	=$edef
close	=$f642
	lda #<nssload
	ldy #>nssload
	sta loadvec
	sty loadvec+1
	lda #<nss
	ldy #>nss
	jmp strout
nss	.byte "nss verify support by nh 090286"
	.byt 13,0
falsch	.byt 13
	.byte "unterschied in "
	.byt 0
nssload	cmp #0
	bne verify
old	jmp loadold
verify	sta love
	lda #0
	sta status
	lda ga
	cmp #4
	bcc old
	ldy fnlen
	bne nonull
	jmp missing
nonull	ldx #sa
	jsr search
	lda #$60
	sta sa
	jsr openfile
	lda ga
	jsr talk
	lda sa
	jsr second
	jsr iecin
	sta mem
	lda status
	lsr
	lsr
	bcs timeout
	jsr iecin
	sta mem+1
	txa
	bne seknonu
	lda adr
	sta mem
	lda adr+1
	sta mem+1
seknonu	jsr message
weiter	lda #$fd
	and status
	sta status
	jsr stopkey
	bne nostop
	jmp fileclose
nostop	jsr iecin
	tax
	lda status
	lsr
	lsr
	bcs weiter
	txa
	ldy #0
	cmp (mem),y
	beq richtig
	lda #$10
	jsr setst
	lda #<falsch
	ldy #>falsch
	jsr strout
	ldx mem
	lda mem+1
	jsr axout
richtig	inc mem
	bne noinc
	inc mem+1
noinc	bit status
	bvc weiter
	jsr untalk
	jsr close
	bcc ausklang
timeout	jmp nofound
ausklang	jsr return
	jmp ende